Drawing - Sélectionner une ligne

Voir le sujet précédent Voir le sujet suivant Aller en bas

EnCours Drawing - Sélectionner une ligne

Message par Bernie12 le Ven 17 Juin 2016 - 21:30

Bonjour à tous les fans de ScriptVBA,

J'aimerais sélectionner (ou détecter) une ligne dans un drawing grâce à la macro VBA et trouver les coordonnées de ses points d'extrémités. J'en ai besoin pour la suite du programme. Pourriez-vous m'aider à trouver ce code ?

N'hésitez pas à me contacter si le sujet n'est pas clair.
Je vous remercie d'avance si vous m'aidez à le trouver.

Bernie12 Smile Smile Smile

Bernie12
timide
timide

Messages : 12
Date d'inscription : 30/10/2015
Localisation : Argenteuil

Revenir en haut Aller en bas

EnCours Re: Drawing - Sélectionner une ligne

Message par raphael_59240 le Ven 17 Juin 2016 - 23:15

Bonjour,

Je pense que tu devrai nous donner un peu plus d'explication car si tu as un drawing, tu as donc une multitude de ligne donc sélectionner une ligne avec quel critère, quel condition....?

cdt,

raphael

avatar
raphael_59240
actif
actif

Messages : 123
Date d'inscription : 28/03/2015
Age : 46
Localisation : dunkerque

Revenir en haut Aller en bas

EnCours Re: Drawing - Sélectionner une ligne

Message par Bernie12 le Sam 18 Juin 2016 - 0:31

Merci pour ta réponse, Rafa ! Smile Smile Smile

Par exemple, il faut prendre un drawing vierge et vous mettre dans le fond de calque dans lequel vous tracez une droite (toute simple et toute bête). Sur cet exemple, j'aimerais grâce à une macro sélectionner cette droite et obtenir les coordonnées des points d'extrémité de cette droite.

Votre aide est toujours la bienvenue.

Bernie12

Bernie12
timide
timide

Messages : 12
Date d'inscription : 30/10/2015
Localisation : Argenteuil

Revenir en haut Aller en bas

EnCours Re: Drawing - Sélectionner une ligne

Message par lumpazepfel le Mar 21 Juin 2016 - 22:41

Salut Bernie,

Ci dessous un petit code qui demande à l'utilisateur de sélectionner une droite tracée dans un CATDrawing et qui affiche les coordonnées des deux extrémités.

Code:
' macro pour afficher les coordonéées des extrémité d'une ligne
' http://catiav5.forumactif.org/t1466-drawing-selectionner-une-ligne#6554
Sub CATMain()

' *** Vérifie si le document actif est un CATDrawing ***

On Error Resume Next
Set MonDessin = Catia.ActiveDocument
If (Err.Number <> 0) Then
    MsgBox ("Un CATDrawing doit être actif")
   
    Exit Sub
End If
If (InStr(MonDessin.Name, ".CATDrawing")) = 0 Then
    MsgBox ("La fenêtre active doit être un CATDrawing")
        Exit Sub
End If
Err.Clear
On Error GoTo 0

' ***  Sélection de la ligne                        ***

Dim maLigne As Line2D
Dim maVue As DrawingView
Set Selection1 = MonDessin.Selection
Dim InPutObjectType(0)
InPutObjectType(0) = "Line2D"
' ***  Demande à l'utilisateur de sélectionner une ligne ***
Status = Selection1.SelectElement2(InPutObjectType, "Selectionner une ligne ", False)
    If (Status = "Cancel") Then Exit Sub
Dim SelectedElement1
Set SelectedElement1 = Selection1.Item(1)
Set maLigne = SelectedElement1.Value

' ***  Recherche des points                          ***

Set monPointDebut = maLigne.StartPoint
Dim StartCoordinates(1)
monPointDebut.GetCoordinates StartCoordinates
MsgBox "Point Départ X=" & StartCoordinates(0) & " / Y=" & StartCoordinates(1)

Set monPointFin = maLigne.EndPoint
Dim EndCoordinates(1)
monPointFin.GetCoordinates EndCoordinates
MsgBox "Point fin X=" & EndCoordinates(0) & " / Y=" & EndCoordinates(1)

End Sub
avatar
lumpazepfel
actif
actif

Messages : 141
Date d'inscription : 03/11/2015
Localisation : Ensisheim

Revenir en haut Aller en bas

EnCours Re: Drawing - Sélectionner une ligne

Message par Contenu sponsorisé


Contenu sponsorisé


Revenir en haut Aller en bas

Voir le sujet précédent Voir le sujet suivant Revenir en haut

- Sujets similaires

 
Permission de ce forum:
Vous ne pouvez pas répondre aux sujets dans ce forum